source: extensions/Crearbo_piwigo/crea_arbo_piwigo.bat @ 13259

@echo off

rem --   ici définir les variables :   --
set Dirnconvert="C:\Program Files\XnView\nconvert.exe"
set OPT=-opthuff -i -rflag decr -rexifthumb -rtype lanczos -ratio -dct 2 -subsampling 2 -32bits
set OPT1=-q 80 %OPT% -resize 800 800
set OPT2=-q 95 %OPT% -resize 1280 1280
set OPT3=-q 70 %OPT% -resize 128 128 -rmeta
set in=*.*
set dest=convertis

set i=2
if exist %1\nul set i=1
if exist %1\* set i=1

if %i%==1 (cd /d %1) else (cd /d %~dp1)

md %dest%
md %dest%\thumbnail
md %dest%\pwg_high

if %i%==1 (
echo conversion des fichiers d'un repertoire
echo repertoire : %1

%Dirnconvert% %OPT1% -out jpeg -o %dest%\%%.jpg %in%
%Dirnconvert% %OPT2% -out jpeg -o %dest%\pwg_high\%%.jpg %in%
%Dirnconvert% %OPT3% -out jpeg -o %dest%\thumbnail\TN-%%.jpg %in%
) else (
echo conversion d'une selection de fichiers
echo liste : %*

for %%A in (%*) do (
%Dirnconvert% %OPT1% -out jpeg -o %dest%\%%.jpg %%A
%Dirnconvert% %OPT2% -out jpeg -o %dest%\pwg_high\%%.jpg %%A
%Dirnconvert% %OPT3% -out jpeg -o %dest%\thumbnail\TN-%%.jpg %%A
)
)


echo  -----------------------------------
echo operation terminee :)
dir *.* /s > contenu.txt
pause>nul
cls