source: extensions/pLoader/trunk/src/Uploader/GUI/ListCtrlProgress.pm @ 6494

package Uploader::GUI::ListCtrlProgress;
use strict;
use Wx qw/
    wxDefaultPosition
    wxDefaultSize
    wxGA_SMOOTH
/;

use base qw/Wx::ListCtrl Class::Accessor::Fast/;
__PACKAGE__->mk_accessors(qw/
        progress_column
        progress_bars
        items
        column_item_data
        item_data
    /
);
use Data::Dumper;

sub new {
    # have to remove class name from @_ because we cannot have 
    # it in @_ when passed to SUPER::new
    my $class  = shift ;

    my ( $self ) = $class->SUPER::new(@_);

    $self->progress_bars([]);
    $self->item_data([]);

    Wx::Event::EVT_PAINT(
        $self,
        sub {
            my ( $self, $event ) = @_;

            eval { $self->paint_progress_bars; };
            $event->Skip;
        }
    );


    $self;
}


sub replace_item_data {
    my ( $self, $item, $data ) = @_;

    $self->item_data->[$item] = $data;
    $self->progress_bars->[$item] ||= Wx::Gauge->new(
        $self,
        -1,
        100,
        wxDefaultPosition,
        wxDefaultSize, 
        Wx::wxGA_SMOOTH
    );

    my $progress_bar = $self->progress_bars->[$item];
    $self->paint_progress_bar($item, $progress_bar);
    $self->RefreshItem($item);
}


sub add_progress_items {
    my ( $self, $added_items ) = @_;

    push @{$self->item_data}, @{$added_items};

    $self->SetItemCount(scalar @{$self->item_data});
}


sub OnGetItemText {
    my ( $self, $item, $column ) = @_;

    my $value = $self->column_item_data->{$column}->(
        $self->item_data->[$item]
    );

    # progress column
    if( $column == $self->progress_column ){
        $self->set_item_progress_value(
            $item,
            $value
        );
        $value = '';
    }

    return $value;
}



sub get_item_progress_rect {
    my ( $self, $item, $subitem ) = @_;

    my $rect = $self->GetItemRect($item);
    #my $pos = $self->GetItemPosition($item);
    # cumulate columns widths. If progress bar is column 4, 
    # cumulate columns widths 0, 1, 2, 3
    my $x = $rect->GetX;

    map { $x += $self->GetColumnWidth($_) } grep { $_ < $subitem } (0..$subitem);
    $rect->SetX($x);
    $rect->SetWidth(
        $self->GetColumnWidth($subitem)
    );

    $rect;
}


sub set_item_progress_value {
    my ( $self, $indx, $value ) = @_;

    my $item = $self->progress_bars->[$indx];

    return unless defined $item;

    if( $value > -1 ){
        $item->SetValue($value);
    }
    else{
        $item->Pulse;
    }
}


sub paint_progress_bars {
    my ( $self ) = @_;

    # re-paint progress bars at the right position and size
    my $i=0;
    map{
        $self->paint_progress_bar($i, $_);
        $i++;
    }@{$self->progress_bars};
}


sub paint_progress_bar {
    my ( $self, $item, $progress_bar ) = @_;

    my $rect = $self->get_item_progress_rect($item, $self->progress_column);
    # top most visible item
    $self->{_y_top} ||= $rect->GetY;

    # hidden
    my $bar_pos = Wx::Point->new(-1000, -1000);

    if(  $rect->GetY >=  $self->{_y_top}) {
        $bar_pos = $rect->GetPosition;
    }

    $progress_bar->Move(
        $bar_pos
    );

    $progress_bar->SetSize(
        $rect->GetSize
    );
}



1;